1. Haiku

Programa para generar versos por ordenador.

Ejercicios

  1. Ejecutar el siguiente programa en Arduino. Para que aparezca la primera estrofa se debe abrir el Monitor Serie. Cada vez que se envía un carácter, aparece una estrofa nueva.

      1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
    /*
  Programa para generar poemas con Arduino.

  Este programa escoge palabras y frases de una base de datos
  para generar versos de forma aleatoria.

  Según se van generando, los versos se envían por el puerto
  serie de comunicaciones hacia el ordenador.

  Al final de cada estrofa, Arduino espera a que se envíe un
  dato cualquiera para continuar.
  Cuando recibe datos, Arduino devuelve tantas estrofas como
  caracteres reciba.
*/

/***********************************************************
   Base de datos de palabras y frases
 ***********************************************************/
const char *palabras[] = {
   "ESCABULLENDOSE",
   "PISANDO",
   "CONTEMPLANDO",
   "MARCHITO",
   "ESCULPIDO",
   "ESCONDIDO",
   "CONFINADO",
   "ATORMENTADO",
   "DOBLANDO",
   "RETORCIENDO",
   "GOLPEANDO",
   "COLGANDO",
   "ENVOLVIENDO",
   "TRANSPARENTE",
   "CANSADO",
   "HACIA LA TIERRA",
   "CASACADA",
   "SACRIFICADOR",
   "RESBALADIZO",
   "EN PEDAZOS",
};

const char *frases[] = {
   "EN LA FRIA CORRIENTE",
   "AJENO A UN MUNDO DE BELLEZA",
   "OLAS TRANQUILAS",
   "FUERA, DESDE EL ABISMO",
   "SOMBRIO, SOMBRIO",
   "EN LA NEGRURA DE LA OSCURIDAD",
   "COGI TUS POEMAS",
   "APAGUE LA LAMPARA",
   "SE ME CIERRAN LOS OJOS",
   "AQUELLOS QUE ESTAN A LA IZQUIERDA",
   "LAS MUJERES DE CIENCIA",
   "LOS HOMBRES DE ACCION",
   "ME APRESURO",
   "POR QUE DESPERDICIARIAS",
   "CUANDO NOS ENCONTRAREMOS DE NUEVO?",
   "DURMIENDO UN POCO",
   "Y CON MUCHA PENA",
   "POR ESTOS POCOS PASOS",
   "AHORA, AL ANOCHECER",
   "HICE PROVECHOSAMENTE",
};


/***********************************************************
   Inicialización y función principal
 ***********************************************************/

void setup() {
   Serial.begin(9600);
   randomSeed(analogRead(3));
}

void loop() {

   // Elige un tipo de estrofa al azar y la genera
   int option = random(3);
   if (option == 0)  estrofa_x();
   if (option == 1)  estrofa_y();
   if (option == 2)  estrofa_z();
   Serial.println();        // Nueva línea

   // Espera que se envíe un dato por el puerto serie
   while(Serial.available() == 0);

   // Lee un carácter y espera un segundo antes de continuar
   Serial.read();
   delay(1000);
}

/***********************************************************
   Funciones auxiliares
 ***********************************************************/

// Devuelve una palabra al azar de la base de datos
const char *palabra() {
   return palabras[random(sizeof(palabras)/2)];
}

// Devuelve una frase al azar de la base de datos
const char *frase() {
   return frases[random(sizeof(frases)/2)];
}

/*
   Envía por el puerto serie una estrofa con estilo:
   palabra...palabra
      ...palabra
         frase
*/
void estrofa_x() {
   Serial.print(palabra());
   Serial.print("... ");
   Serial.print(palabra());
   Serial.println();        // Nueva línea

   Serial.print("   ...");
   Serial.print(palabra());
   Serial.println();        // Nueva línea

   Serial.print("      ");
   Serial.print(frase());
   Serial.println();        // Nueva línea
}

/*
   Envía por el puerto serie una estrofa con estilo:
   frase
      frase...
         frase
*/
void estrofa_y() {
   Serial.print(frase());
   Serial.println();        // Nueva línea

   Serial.print("   ");
   Serial.print(frase());
   Serial.print("...");
   Serial.println();        // Nueva línea

   Serial.print("      ");
   Serial.print(frase());
   Serial.println();        // Nueva línea
}

/*
   Envía por el puerto serie una estrofa con estilo:
      palabra
   frase
   palabra, frase, frase
*/
void estrofa_z() {
   Serial.print("   ");
   Serial.print(palabra());
   Serial.println();        // Nueva línea

   Serial.print(frase());
   Serial.println();        // Nueva línea

   Serial.print("   ");
   Serial.print(palabra());
   Serial.print(", ");
   Serial.print(frase());
   Serial.print(", ");
   Serial.print(frase());
   Serial.println();        // Nueva línea
}

  2. Modificar el programa anterior con palabras y frases distitintas.

  3. Modificar el programa anterior para que las estrofas tengan una estructura diferente.